Sample: Creating a Wizard

app.ducx Object Model Language

// The graddmemebers property is used to add members to the group
// within the second wizard step
extend class Group {
  unique Object[] graddmembers {
    allow {
      User create;
    }
  }
}

app.ducx User Interface Language

// The form contains the two form pages that are displayed in the first
// and second wizard step
form FormGroupCreateGroupWizApp {
  audience = enduser;
  formpage PageGroupCreateGroupWizApp {
    audience = enduser;
    dataset {
      grlongname;
      grshortname;
      grsupergroups;
      grorgunittype;
      objexternalkey;
    }
  }
  formpage PageMembersCreateGroupWizApp {
    audience = enduser;
    dataset {
      graddmembers;
    }
  }
}

app.ducx Use Case Language

override InitializeCreatedObject {
  variant Group {
    impl = application {
      expression {
        Object venv_object;
        Object venv_parent;
        integer venv_index;
        Object venv_view;
        Object venv_action;
        WizardContext[] @venv_wizardctx;
        Object @group;
        venv_object.ObjectLock(true, true);
        if (venv_parent.HasClass(#Group) && venv_view == #grsubgroups) {
          venv_object.grsupergroups = venv_parent;
        }
        @group = venv_object;
        // Creates the wizard context
        @venv_wizardctx = [
         {@group, #FormGroupCreateGroupWizApp, #ShowWizardApp}
        ];
        // Calls the wizard; the parameters are defined in the
        // FSCVENV@1.1001:WizardPrototype
        ->DoWizardApp(venv_object, venv_parent, venv_index, venv_view,
            venv_action, @venv_wizardctx);
        venv_object.AddUserRole(venv_object.graddmembers, #StaffPos,
            venv_object);
        venv_object.graddmembers = null;
      }
    }
  }
}

// When creating a group the implementation of InitializeCreatedObject
// gets executed
override InitializeCreatedObjectDoDefault {
  variant Group {
    // GroupInitializeCreatedObject is implicitely generated
    // from InitializeCreatedObject with variant Group
    impl = GroupInitializeCreatedObject;
  }
}